Visual Basic Schaltflächenleiste

[NasenBär]

hy!

wenn du ein bild für den button festlegen willst kannst du es auch ohne service pack machen! vielleicht hilft dir dieses beispiel:

Private Sub Form_Load()
' Objektvariable für Abbildungsliste erstellen
Dim imgX As ListImage

' Bilder in Abbildungsliste-Steuerelement laden.
Set imgX = ImageList1.ListImages. _
Add(, "open", LoadPicture("Graphics\bitmaps\tlbr_w95\open.bmp"))
Set imgX = ImageList1.ListImages. _
Add(, "save", LoadPicture("Graphics\bitmaps\tlbr_w95\save.bmp"))
Toolbar1.Imagelist = ImageList1

' Objektvariable für die Symbolleiste erstellen.
Dim btnX As Button
' Button-Objekte mit Hilfe der Add-Methode zur
' Buttons-Auflistung hinzufügen. Nach dem Erstellen
' der einzelnen Schaltflächen Description- und
' ToolTipText-Eigenschaft setzen.
Toolbar1.Buttons.Add , , , tbrSeparator
Set btnX = Toolbar1.Buttons.Add(, "open", , tbrDefault, "open")
btnX.ToolTipText = "Datei öffnen"
btnX.Description = btnX.ToolTipText
Set btnX = Toolbar1.Buttons.Add(, "save", , tbrDefault, "save")
btnX.ToolTipText = "Datei speichern"
btnX.Description = btnX.ToolTipText
Set btnX = Toolbar1.Buttons.Add(, , , tbrSeparator)
' Die nächste Schaltfläche hat den Stil
' "Platzhalter". Ein Kombinationsfeld-Steuerelement
' wird über dieser Schaltfläche plaziert.
Set btnX = Toolbar1.Buttons.Add(, "combo1", , tbrPlaceholder)
btnX.Width = 1500 ' Platzhalter breit genug für
' Kombinationsfeld.

Show ' Formular anzeigen, um Konfiguration des
' Kombinationsfelds fortzusetzen.

' Kombinationsfeld-Steuerelement so konfigurieren,
' daß es am selben Platz wie das Button-Objekt mit
' dem Platzhalterstil (Schlüssel/Key = "combo1")
' sitzt.
With Combo1
.Width = Toolbar1.Buttons("combo1").Width
.Top = Toolbar1.Buttons("combo1").Top
.Left = Toolbar1.Buttons("combo1").Left
.AddItem "Schwarz" ' Farben für den Text
' hinzufügen.
.AddItem "Blau"
.AddItem "Rot"
.ListIndex = 0
End With

End Sub

Private Sub Form_Resize()
' Kombinationsfeld-Steuerelement konfigurieren.
With Combo1
.Width = Toolbar1.Buttons("combo1").Width
.Top = Toolbar1.Buttons("combo1").Top
.Left = Toolbar1.Buttons("combo1").Left
End With

End Sub
Private Sub toolbar1_ButtonClick(ByVal Button As Button)
' Key-Eigenschaft mit der Select Case-Anweisung
' verwenden, um eine Aktion anzugeben.
Select Case Button.Key
Case Is = "open" ' Datei öffnen.
MsgBox "Hier Code für Datei öffnen eingeben!"
Case Is = "save" ' Datei speichern.
MsgBox "Hier Code für Datei speichern eingeben!"
End Select
End Sub

Private Sub Combo1_Click()
' Hintergrundfarben des Fromulars mit dem
' Kombinationsfeld ändern.
Select Case Combo1.ListIndex
Case 0
Form1.BackColor = vbBlack
Case 1
Form1.BackColor = vbBlue
Case 2
Form1.BackColor = vbRed
End Select
End Sub

vielleicht hilfts!
mfg